MIDDEL.HVIS-funktion

Returnerer det aritmetiske gennemsnit af alle celler i et område der tilfredsstiller en given betingelse. MIDDEL.HVIS funktionen summerer alle resultater der passer den logiske test, og dividerer summen med antallet af valgte værdier.

tip

Denne funktion er tilgængelig siden LibreOfficeDev4.0


Syntaks

MIDDEL.HVIS(Område; Kriterie [; Gennemsnit_Område])

Område – påkrævet argument. Et område, navnet på et navngivet område eller en etiket for en kolonne eller en række, som indeholder gennemsnitstal, tal eller tekst for betingelserne.

Kriterium – krævet argument. En betingelse i form af et udtryk eller en cellereference med et udtryk som definerer hvilke celler der skal bruges til at udregne gennemsnittet. Udtrykket kan bestå af tekst, tal, regulære udtryk (hvis aktiveret i beregningsindstillingerne) eller jokertegn (hvis aktiveret i beregningsindstillingerne).

The search supports wildcards or regular expressions. With regular expressions enabled, you can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must either precede every character with a "\" character, or enclose the text into \Q...\E. You can switch the automatic evaluation of wildcards or regular expression on and off in - LibreOfficeDev Calc - Calculate.

warning

When using functions where one or more arguments are search criteria strings that represents a regular expression, the first attempt is to convert the string criteria to numbers. For example, ".0" will convert to 0.0 and so on. If successful, the match will not be a regular expression match but a numeric match. However, when switching to a locale where the decimal separator is not the dot makes the regular expression conversion work. To force the evaluation of the regular expression instead of a numeric expression, use some expression that can not be misread as numeric, such as ".[0]" or ".\0" or "(?i).0".


Gennemsnit_Område – valgfrit. Det er et område af værdier, som der skal beregnes gennemsnit for.

note

If the Average_Range is not specified, Range is used for both, the calculation of the mean and the search according to the condition. If Average_Range is specified, the Range is used only for the condition test, while Average_Range is used for the average calculation.


Noteikon

Denne funktion er en del af Open Document Format for Office Applications (OpenDocument) standard Version 1.2. (ISO/IEC 26300:2-2015)


warning

Hvis en celle i et område af værdier, som der skal beregnes middelværdi for, er tom eller indeholder tekst, ignorerer funktionen MIDDEL.HVIS cellen.
Hvis hele området er tomt, kun indeholder tekst, eller samtlige værdier ikke tilfredsstiller betingelserne (eller en kombination af dem), returnerer funktionen fejlen #DIV/0!.


Eksempel

Betragt den følgende tabel

A

B

C

1

Produktnavn

Salg

Indtægt

2

blyant

20

65

3

kuglepen

35

85

4

notesblok

20

190

5

bog

17

180

6

penalhus

ikke

ikke


warning

I alle eksempler herunder, indeholder området for beregning af summen række #6, men den ignoreres, fordi den indeholder tekst.


warning

I alle beregninger herunder, indeholder området for beregning af middelværdien række #6, men den ignoreres, fordi den indeholder tekst.


Simpelt brug

=MIDDEL.HVIS(B2:B6;"<35")

Beregner gennemsnittet for værdier i området B2:B6 som er mindre end 35. Returnerer 19, fordi anden række ikke medregnes i gennemsnittet.

=MIDDEL.HVIS(B2:B6;"<"&MAX(B2:B6))

Beregner gennemsnittet for værdierne i det samme område, som er mindre end den maksimale værdi i dette område. Returnerer 19, fordi den højeste værdi (anden række) ikke medregnes i gennemsnittet.

=MIDDEL.HVIS(B2:B6;">"&MINDSTE(B2:B6;1))

Beregner gennemsnittet af værdier i det samme område, som er større end den første mindste værdi i området. Returnerer 25, fordi den første mindste værdi (fjerde række) ikke medregnes i gennemsnittet.

Brug af gennemsnit_område

=MIDDEL.HVIS(B2:B6;"<35";C2:C6)

Funktionen finder de værdier, som er mindre end 35 i området B2:B6, og beregner gennemsnittet af korresponderende værdier fra området C2:C6. Returnerer 145, fordi anden række ikke medregnes i beregningen.

=MIDDEL.HVIS(B2:B6;">"&MIN(B2:B6);C2:C6)

Funktionen finder de værdier fra området B2:B6, som er større end den mindste værdi og beregner gennemsnittet af korresponderende værdier fra området C2:C6. Returnerer 113,3, fordi fjerde række (hvor den mindste værdi er) ikke medregnes i beregningen.

=MIDDEL.HVIS(B2:B6;"<"&STØRSTE(B2:B6;2);C2:C6)

Denne funktion finder hvilke værdier fra området B2:B6 som er mindre end den næsthøjeste værdi i området B2:B6, og beregner gennemsnittet for de korresponderende værdier fra området C2:C6. Returnerer 180, fordi kun fjerde række indgår i beregningen.

Brug af regulære udtryk

=MIDDEL.HVIS(A2:A6;"pen";B2:B6)

Denne funktion finder de celler fra området A2:A6 som indeholder ordet “pen”, og beregner gennemsnittet af de korresponderende værdier fra området B2:B6. Returnerer 35, fordi kun den anden række indgår i beregningen. Søgningen sker i området A2:A6, men værdierne returneres fra området B2:B6.

=MIDDEL.HVIS(A2:A6;"pen.*";B2:B6)

Denne funktion finder de celler i området A2:A6 som begynder med “pen” og slutter med enhver kombination af tegn, og beregner gennemsnittet af værdierne fra det korresponderende område B2:B6. Returnerer 27,5, fordi også ordet “pencil” lever op til betingelserne, og både første og anden række indgår i beregningen.

=MIDDEL.HVIS(A2:A6;".*book.*";B2:B6)

Denne funktion finder de celler i området A2:A6 som indeholder “book” og starter eller slutter med enhver kombination af tegn, og beregner gennemsnittet af værdierne fra det korresponderende område B2:B6. Returnerer 18,5, fordi kun tredje og fjerde række indgår i beregningen.

Reference til en celle som kriterie

Hvis du har brug for let at ændre et kriterie, kan du angive det i en separat celle og bruge en reference til denne celle i betingelsen i MIDDEL.HVIS-funktionen.

=MIDDEL.HVIS(A2:A6;".*"&E2&".*";B2:B6)

Denne funktion finder hvilke celler i området A2:A6 som indeholder en kombination af tegn som specificeres i E2 startende og sluttende med enhver kombination af tegn, og beregner gennemsnittet af de korresponderende værdier fra området B2:B6. Hvis E2 = book, returnerer funktionen 18,5.

=MIDDEL.HVIS(B2:B6;"<&E2;C2:C6)

Denne funktion finder de celler fra området A2:A6 som er mindre end værdien specificeret i E2, og beregner gennemsnittet af de korresponderende værdier fra området B2:B6. Hvis E2 = 35, returnerer funktionen 145.